; Created in LibreOffice 4 with this LibreLogo program.
; Usage: Copy it in an English language document in LibO Writer,
; and click on the Start icon of the View»Toolbar»Logo toolbar.
TO superior num prevnum
s = “”
FOR i IN STR num [
s = s + “⁰¹²³⁴⁵⁶⁷⁸⁹”[INT i]
]
IF NOT prevnum % 10 = 1 [ s = “ ” + s ] ; narrow space
OUTPUT s
END
TO inferior num
s = “”
FOR i IN STR num [
s = s + “₀₁₂₃₄₅₆₇₈₉”[INT i]
]
OUTPUT s
END
CLEARSCREEN HIDETURTLE FONTSIZE 18 FONTFAMILY “DejaVu Sans”
FOR vertices IN [7, 11, 13, 14, 16, 17, 19] [
; PICTURE “poly/regular_polygon_%d_annotated.svg” % vertices [ ; from LibO 4.1.1
PICTURE [
HOME FILLCOLOR “WHITE” PENCOLOR “SILVER”
PENDOWN PENSIZE 2 CIRCLE 400
β = 360/vertices
q = vertices // 4
CIRCLE [80 + vertices * 14, 80 + vertices * 14, β * q, β * (q + 1)]
FONTCOLOR “SILVER”
IF vertices > 18 [ f = 0.004 ] [ f = 0.005 ]
HEADING β * q + β * 0.5 PENUP
FORWARD (80 + vertices * 14) * (0.3 + (f * vertices))
HEADING 0
s1 = superior (360 % vertices, 360 // vertices)
s2 = inferior vertices
LABEL “%d%s⁄%s°” % (β, s1, s2)
HOME HEADING 0 PENDOWN
dots = []
REPEAT vertices [
FORWARD 200
where = POSITION
dots = dots + [where]
BACK 200 RIGHT β
]
HOME PENSIZE 2 CIRCLE 10
PENCOLOR “BLACK” FONTCOLOR “BLACK”
α = ((vertices-2)/vertices)*180
PENUP FORWARD 200 PENDOWN
CIRCLE [100 + 105/vertices, 100 + 105/vertices, 180 – α/2, 180 + α/2]
s1 = superior ((vertices-2) * 180 % vertices, INT α)
PENUP BACK 20 + 70/vertices LABEL “%d%s⁄%s°” % (α, s1, s2)
HOME PENUP PENSIZE 4 PENUP
FOR i IN dots + dots[0:1] [ POSITION i PENDOWN ] PENSIZE 2
FOR i IN dots [ PENUP POSITION i PENDOWN CIRCLE 10 ]
]
]
Αδειοδότηση
László Németh, ο κάτοχος των πνευματικών δικαιωμάτων αυτού του έργου, το δημοσιεύει δια του παρόντος υπό την εξής άδεια χρήσης:
Το πρόσωπο που συσχέτισε ένα έργο με αυτή την πράξη έχει απελευθερώσει αυτό το έργο στην δημόσια σφαίρα παραιτούμενος από όλα τα δικαιώματά του σε αυτό το έργο παγκοσμίως υπό τη νομοθεσία των πνευματικών δικαιωμάτων και όλα τα σχετικά ή παρεμφερή νόμιμα δικαιώματα που είχε στο έργο, στο εύρος που νόμος ορίζει. Έργα υπό την CC0 δεν χρειάζονται απόδοση. Όταν παραθέτετε το έργο, δε χρειάζεται να υπαινιχθείτε έγκριση από το συγγραφέα.
http://creativecommons.org/publicdomain/zero/1.0/deed.enCC0Creative Commons Zero, Public Domain Dedicationfalsefalse
Αυτό το αρχείο περιέχει πρόσθετες πληροφορίες, πιθανόν από την ψηφιακή φωτογραφική μηχανή ή το scanner που χρησιμοποιήθηκε για την δημιουργία ή την ψηφιοποίησή της. Αν το αρχείο έχει τροποποιηθεί από την αρχική του κατάσταση, ορισμένες λεπτομέρειες πιθανόν να μην αντιστοιχούν πλήρως στην τροποποιημένη εικόνα.